
**Comparing period-to-date with previous full period**



Sales PYC :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year] ),

    CALCULATE (

        [Sales Amount],

        PARALLELPERIOD ( 'Date'[Date], -1, YEAR )

    )

)

Sales YTDOPY :=

VAR ValueCurrentPeriod = [Sales YTD]

VAR ValuePreviousPeriod = [Sales PYC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales YTDOPY % :=

DIVIDE (

    [Sales YTDOPY],

    [Sales PYC]

)

Sales PYC (2) :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year] ),


    CALCULATE (

        [Sales Amount],

        PREVIOUSYEAR ( 'Date'[Date] )

    )

)



The measures used in the report are defined as follows. Please pay attention to the second argument of [**PREVIOUSYEAR**](https://dax.guide/previousyear/?aff=dax-patterns) in Sales Fiscal PYC:

Sales Fiscal PYC :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        PREVIOUSYEAR ( 'Date'[Date], "06-30" )

    )

)

Sales Fiscal YTDOPY :=

VAR ValueCurrentPeriod = [Sales Fiscal YTD]

VAR ValuePreviousPeriod = [Sales Fiscal PYC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result


Sales Fiscal YTDOPY % :=

DIVIDE (

    [Sales Fiscal YTDOPY],

    [Sales Fiscal PYC]

)



The quarter-to-date-over-previous-quarter growth is computed with the Sales QTDOPQ and Sales QTDOPQ % measures; these rely on the Sales QTD measure to compute the quarter-to-date value and on the Sales PQC measure to get the sales amount of the entire previous quarter:

Sales PQC :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Quarter] ),

    CALCULATE (

        [Sales Amount],

        PARALLELPERIOD ( 'Date'[Date], -1, QUARTER )

    )

)

Sales QTDOPQ :=

VAR ValueCurrentPeriod = [Sales QTD]

VAR ValuePreviousPeriod = [Sales PQC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales QTDOPQ % :=

DIVIDE (

    [Sales QTDOPQ],

    [Sales PQC]

)

Sales PQC (2) :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Quarter] ),


    CALCULATE (

        [Sales Amount],

        PREVIOUSQUARTER ( 'Date'[Date] )

    )

)



The month-to-date-over-previous-month growth is computed with the Sales MTDOPM % and Sales MTDOPM measures; these rely on the Sales MTD measure to compute the month-to-date value and on the Sales PMC measure to get the sales amount of the entire previous month:

Sales PMC :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Month] ),

    CALCULATE (

        [Sales Amount],

        PARALLELPERIOD ( 'Date'[Date], -1, MONTH )

    )

)

Sales MTDOPM :=

VAR ValueCurrentPeriod = [Sales MTD]

VAR ValuePreviousPeriod = [Sales PMC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales MTDOPM % :=

DIVIDE (

    [Sales MTDOPM],

    [Sales PMC]

)

The *Sales PMC* measure can also be written using [**PREVIOUSMONTH**](https://dax.guide/previousmonth/?aff=dax-patterns), as long as it is not used at the quarter or year level for more than one month:

**Measure in the Sales table**

Sales PMC (2) :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Month] ),

    CALCULATE (

        [Sales Amount],

        PREVIOUSMONTH ( 'Date'[Date] )

    )

)